Flash AS 实例进阶 制作时钟实现代码
源文件下载
>点击查看动画效果<实例2-6时钟
基本思路
① 作 3 个指针 MC ，分别按不同的速度旋转，实现时钟效果。
②若 要拖拽效果，则要把 12 个数字分别作成 MC 。然后作鼠标跟随。
新知识点 ① Date 类的方法的应用：
MY Date= new Date()// 构造一个新的 Date 对象
Date.getHours()// 按照本地时间返回小时值。
Date.getMinutes()// 按照本地时间返回分钟值。
Date.getSeconds()// 按照本地时间返回秒数。
Date.getMilliseconds()// 按照本地时间返回毫秒值。
②一种缓冲公式应用
实例说明
①此时钟实例是由数字和指针共 15 个 MC 组成，并又是嵌套在 MC “ biao” 中，各 MC 的注册点一定要确定准确，
② 分别将 MC “ biao” 放在主时间轴的 3 个帧上，为各帧上的 MC 编写不同的脚本。
③ 设一按钮用于各帧之间的跳转
编写动作脚本 ① 在第 1 帧到第 2 帧的 MC 上输入：
onClipEvent (enterFrame) {// 以影片剪辑帧频不断触发的动作
s = new Date();// 创健日期对象
Hours = s.getHours();// 读取系统时间 - 时
if (12<Hours) {
Hours = Hours-12;
}// 把 24 小时制转换为 12 小时制
this.b13._rotation = ((Hours*30)+(s.getMinutes()/2)); // 把时和分转换为旋转角度
this.b14._rotation = (6*s.getMinutes()); // 把获取的系统时间分转换为旋转角度
this.b15._rotation = (6*s.getSeconds()); // 把获取的系统时间秒转换为旋转角度
}
② 在第 3 帧的 MC 上输入：
onClipEvent (load) {变量初始化
for (i=1; i<16; i++) {
this["b"+i].xl = 0;
this["b"+i].yl = 0;
}
}
onClipEvent (enterFrame) {
s = new Date();
Hours = s.getHours();
if (12<Hours) {
Hours = Hours-12;
}
this.b13._rotation = ((Hours*30)+(s.getMinutes()/2));
this.b14._rotation = (6*s.getMinutes());
this.b15._rotation = (6*s.getSeconds());
this.b1._x = _xmouse;
this.b1._y = _ymouse+120; // 让第一个 MC 跟随鼠标移动 ,并要MC低于鼠标120个像素。
for (i=2; i<=15; i++) {
this["b"+i].xl = (this["b"+(i-1)]._x-this["b"+i]._x)/2+this["b"+i].xl*0.3;// 变量 bi.xl 在趋于 0 的过程中不断被赋新值
this["b"+i].yl = (this["b"+(i-1)]._y-this["b"+i]._y)/2+this["b"+i].yl*0.3;// 变量 bi.yl 在趋于 0 的过程中不断被赋新值
this["b"+i]._x += this["b"+i].xl;//MC “ bi ”的坐标 x 值
this["b"+i]._y += this["b"+i].yl;//MC “ bi ”的坐标 y 值
}
}
③ 在第 1 帧上输入：
stop();
④ 在第 2 帧上输入：
biao.startDrag(true);
⑤在第 1 帧到第 2 帧的按钮上输入：
on (release) { nextFrame();}
⑤在第 3 帧的按钮上输入：
on (release) { gotoAndStop(1);}要点分析 ① 时针： this.b13._rotation = ((Hours*30)+(s.getMinutes()/2))
首先看 ((Hours*30) ，因为走一周 12 小时是 360 度，那每小时就是走 30 度，用本地时间的小时数乘于 30 就是指针指向的度数。，如 3 点就是 3*30 ，指针在 90 度位置，但这样只能是按小时发生动作，要显示中间的指针变化还需加上 (s.getMinutes()/2) ，这个表达式是计算的当前分钟乘于每分钟在一个小时刻度内走的度数（ 0.5 度），这两个表达式相加就是以小时和分钟计算出的时针旋转度数。
② 缓冲公式： this["b"+i].xl = (this["b"+(i-1)]._x-this["b"+i]._x)/2+this["b"+i].xl*0.3;
为便于观看首先把数值具体化： b2.xl=( b1._x-b2._x)/2+b2.xl*0.3; 其中的 ( b1._x-b2._x)/2 ，我们在导航条那课已经用过类似的方法，这里是取两个 MC 坐标值的差的二分之一，这个表达式的结果在不断的由大到小直至为 0 ，其中的 b2.xl*0.3 ， 是有意增加的偏差值， 有叫抖动率的，也是由大到小变化最后到 0 ，这两个表达式计算的结果赋给变量 b2.xl ，有了这样的公式，鼠标跟随就会有延时和抖动效果。
小结本讲学习的目的是掌握时钟的运动原理，此外还学习 一种缓冲公式的运用，也是很有实用价值的内容，希望课下能用数字代入加深理解。
课后练习不要秒针跳跃式旋转，而要平缓连贯地旋转，范例效果：
>点击查看动画效果<练习2-６
>点击查看动画效果<练习2-６-2
查看全套"Flash AS 实例进阶教程"
IT时代网(关注微信公众号ITtime2000，定时推送，互动有福利惊喜)所有原创文章版权所有，未经授权，转载必究。
创客100创投基金成立于2015年，直通硅谷，专注于TMT领域早期项目投资。LP均来自政府、互联网IT、传媒知名企业和个人。创客100创投基金对IT、通信、互联网、IP等有着自己独特眼光和丰富的资源。决策快、投资快是创客100基金最显著的特点。
TA的最新文章
热门文章
精彩评论
-
小何华为现在牛的不只是设备商了，，华为的手机现在也是全球销量不错，国内也算是老大了，之前用小米，，现在都改华为了。。产品确实不错。 -
小何三星手机在中国还有市场吗？看看现在满大街的vivo和oppo ，，华为，，小米线下店，，就是知道三星的市场基本没有了。。
-
小何滴滴打车现在也没有之前那么火了，，补贴也少了。。
-
小何今日头条要把腾讯的地方各频道给霸占了。。